/*
	The query computes in real time the value of a portfolio.
	The portfolio is described in the query using some in-lined
	XML ([[ .. ]]).
	
	Based on the portfolio, a URL is computed to access a <A
	href="http://db.cis.upenn.edu/W4F">W4F</A> Web service that will
	return the current stock price.
	
	Then the query enriches the portfolio with the price information.
	Finally, the quey computes the grand total.

*/

FUNCTION YAHOO_FINANCE( $portfolio )
{
	document( CONCAT( "http://db.cis.upenn.edu/cgi-bin/YFS.pl?",
		          JOIN("+", $portfolio/ASSET/@NAME, "NOK"),
                          "&d=t" ) )
}

LET $portfolio :=
      [[
      <PORTFOLIO>
        <ASSET NAME="LU"   QTY="35"/>
        <ASSET NAME="IBM"  QTY="20"/>
        <ASSET NAME="NOK"  QTY="120"/>
        <ASSET NAME="CSCO" QTY="65"/>
        <ASSET NAME="TXN"  QTY="80"/>
      </PORTFOLIO>
      ]],
    $yahooFinance := YAHOO_FINANCE($portfolio)

RETURN

  <PORTFOLIO>

    (
    FOR $asset IN $portfolio/ASSET
    LET $price := $yahooFinance/Stock[ ./@Ticker = $asset/@NAME ]/LastPrice
    RETURN
      <ASSET NAME  = $asset/@NAME
             QTY   = $asset/@QTY
             PRICE = CONCAT("$", TRIM($price))
             VALUE = CONCAT("$", $price * $asset/@QTY) />
     SORTBY ( ./@NAME )
    ),

    <TOTAL>
    CONCAT("$",
      SUM( FOR $asset IN $portfolio/ASSET
           LET $price := $yahooFinance/Stock[ ./@Ticker = $asset/@NAME ]/LastPrice
           RETURN $asset/@QTY * $price ) )
    </TOTAL>

  </PORTFOLIO>